Arduino Scalar Network Analyzer, 60 MHz, 80 dB

Shield "TOBI"

✈ Hardware / Software Description

✈ Arduino Sketch - The Code

Double click on code to select ...

// AD9851 DDS and AD8307 power meter
// sept 2013 RH
// small adjustments to match this project:
// https://www.changpuak.ch/electronics/Arduino-Shield-TOBI.php
// 02.11.2015 Alexander Frank

unsigned long DDS_CLOCK = 150000000 ;     // PLUS MINUS SOME PPM
unsigned long FREQ = 10625048 ;
unsigned long FTW ;
unsigned long REF_MUL = 0x0000 ;
 
// THIS IS FOR VERSION 2
int DATA = A4;
int CLOCK = A2; 
int UPDATE = A3; 
int AD8307 = A1;
char inputcmd[100];  // serial data input
int cmdindex=0;

void dBm_power() 
{
  float dBm=0;
  int i;
  for (i=0;i<20;++i)  dBm+=(float)analogRead(AD8307); // average
  dBm=dBm/i;
  dBm = dBm - 869;
  dBm = ( dBm * 0.1014342 ) - 6.6 ;    
  Serial.print(" "); // may help Python parser
  Serial.print(dBm);
  Serial.println(" "); // may help Python parser
}

void raw_power() 
{
  Serial.print(" "); // may help Python parser
  Serial.print(analogRead(AD8307));
  Serial.println(" "); // may help Python parser
}

void SetFrequency(unsigned long frequenz)
{
FTW = (frequenz * pow(2, 24)) / ( DDS_CLOCK/256 ) ;

unsigned long pointer = 0b00000000000000000000000000000001 ;
for (int i=0; i<32; i++)
  {
    if ((FTW & pointer)>0) { digitalWrite(DATA, HIGH); }
      else { digitalWrite(DATA, LOW); }
    digitalWrite(CLOCK, HIGH);
    digitalWrite(CLOCK, LOW);
    pointer = pointer << 1 ;
  }
 
pointer = 0b00000000000000000000000000000001 ;
 
for (int i=0; i<8; i++)
  {
    if ((REF_MUL & pointer)>0) { digitalWrite(DATA, HIGH); }
      else { digitalWrite(DATA, LOW); }
    digitalWrite(CLOCK, HIGH);
    digitalWrite(CLOCK, LOW);
    pointer = pointer << 1 ;
  }
digitalWrite(UPDATE, HIGH);
digitalWrite(UPDATE, LOW);
}

void setup()
{
  Serial.begin(9600);
  
 // init dds 
  pinMode (DATA,  OUTPUT); 
  pinMode (CLOCK, OUTPUT); 
  pinMode (UPDATE,  OUTPUT); 

  SetFrequency(1000000); // 1 MHz default

}

void loop()   // Arduino superloop - where everything gets done
{
  char ch;

  long int temp;
  
// serial command interpreter 
// enter a number to set the frequency, anything else shows power
  while (Serial.available()) {
    ch=(char)Serial.read();
    if (((ch >= '0') && (ch <= '9')) || ((ch >= 'A') && 
    		(ch <= 'Z'))) inputcmd[cmdindex++]=ch; 
    if (ch == '\n') {    // parse command if its a newline
      inputcmd[cmdindex]=0; // terminate the string
      if ((temp=atol(inputcmd)) > 0) SetFrequency(temp);
      else dBm_power();  
      //else raw_power();  // python has trouble with floats
      cmdindex=0; // reset command line      
    }
  }
}

✈ Calibration

✈ Python

✈ Downloads

✈ Pressing the "ACTION" button ... TESTING THAT THING :-)

This very first test measures a ceramic filter for 10.7 MHz with l-c matching network. Even the calibration feature was not used, the result is overwhelming. And the beauty of the graph makes you freak out ...



The second candidate was a Crystal Bandpass Filter from here



The third candidate was a lowpass of MiniCircuits (BLP-10.7)



The fourth measurement shows the finding of crystal replacement data (by measuring the series and the parallel resonant frequency). Go here, if this is interesting for you. With the possibility to store a trace, it is easy to find matching crystals.

✈ Hint

✈ Share your thoughts